DECLARE SUB hp3457preset ()
DECLARE SUB hp3457readv (v!)
DECLARE SUB hp3457setupv (c%)
DECLARE SUB hp3457cv (c%, v!)
DECLARE SUB imagmeas (imag!)
DECLARE SUB hpmxccv (mxcard%, mxchan%, v!)
DECLARE SUB k7011closecc (card%, chan%)
DECLARE SUB k7011openall ()
DECLARE SUB hp3457setuptc (c%)
DECLARE SUB hp3457readtc (tc!)
DECLARE SUB gettestparam ()
DECLARE SUB measure ()
DECLARE SUB logmrt (logfile$, m%, nrt%, tim$(), imag!(), vmag!(), rmag!(), twin!(), twout!(), tiron!(), tcoil!(), tamb!())
DECLARE SUB rmeas (m%, imag!, vmag!, rmag!)
DECLARE SUB tmeas (m%, twin!, twout!, tiron!, tcoil!, tamb!)
DECLARE SUB imagramp (rr!, ifin!)
DECLARE SUB fileheader (logfile$, mn$, op$, ts$, dv$, rn$, cm$)
DECLARE SUB fileinitl (test$, run$, logfile$, ok$)
DECLARE SUB filemkdir (DestDir$)
DECLARE SUB gpibinit ()
DECLARE SUB k7011init ()
DECLARE SUB hp3457init ()
DECLARE SUB dac488hrinit ()
DECLARE SUB dac488hrsetupv ()

'****************************************************************************
'Program HERDRT
'This program is used to measure the resistance and temperature of the
'B-Factory HER dipoles.  It samples the magnet voltage and current to
'get the magnet resistance.  It measures the resistance of several
'thermistors to get magnet temperatures.
'
'Zachary Wolf
'6/5/94
'****************************************************************************

'Include the constants used in the program
REM $INCLUDE: 'param.inc'

'Prepare the screen
CLS

'Initialize the GPIB
CALL gpibinit

'Initialize the DAC
CALL dac488hrinit
CALL dac488hrsetupv

'Initialize the HP3457
CALL hp3457init

'Initialize the K7011 multiplexer
CALL k7011init

'Print a message about the program
PRINT
PRINT "Program HERDRT"
PRINT "This program measures the resistances and temperatures of all three"
PRINT "B-Factory HER dipoles on the test stands."
PRINT
PRINT "The magnet resistances and temperatures will be measured at regular"
PRINT "intervals for as long as you specify.  The measurements will be"
PRINT "made at the current you specify."
PRINT
PRINT

'Get test parameters from the operator
testparam:
CALL gettestparam

'Create the \magdata subdirectory to store the log files
subdir1$ = "c:\magdata\" + magname1P$
CALL filemkdir(subdir1$)

subdir2$ = "c:\magdata\" + magname2P$
CALL filemkdir(subdir2$)

'Initialize the log file
CALL fileinitl(subdir1$ + "\" + "rt", runP$, logfile1P$, ok1$)
CALL fileinitl(subdir2$ + "\" + "rt", runP$, logfile2P$, ok2$)
IF ok1$ <> "y" OR ok2$ <> "y" THEN
 PRINT
 PRINT "Problem initializing the data files."
 PRINT "Make sure you are using a new run number."
 GOTO testparam:
END IF

'Write headers to the log and data files
CALL fileheader(logfile1P$, magname1P$, operatorP$, "D1", "HP thermistors", runP$, commentP$)
CALL fileheader(logfile2P$, magname2P$, operatorP$, "D2", "HP thermistors", runP$, commentP$)

'Perform the measurements
CALL measure

'Message
PRINT
PRINT "Ramping to 0 Amps."

'Ramp to 0 amps
CALL imagramp(imagramprateP!, 0!)

'Message
PRINT "The test is complete."

END

SUB gettestparam

'****************************************************************************
'This subroutine prompts the operator for the magnet name and other
'parameters of the test.
'
'Outputs put in the /testparam/ common block:
'  magname1P$, name of magnet 1
'  magname2P$, name of magnet 2
'  operatorP$, name of the operator doing the test
'  runP$, run number
'  commentP$, comment about the test
'
'Zachary Wolf
'4/16/94
'****************************************************************************

begin:
'Get the name of the magnet on test stand 1
PRINT "What is the name of the magnet on test stand D1?"
PRINT "(8 characters or less): ["; magname1P$; "]";
INPUT magname1$
magname1$ = UCASE$(magname1$)
IF magname1$ <> "" THEN magname1P$ = magname1$

'Get the name of the magnet on test stand 2
PRINT "What is the name of the magnet on test stand D2?"
PRINT "(8 characters or less): ["; magname2P$; "]";
INPUT magname2$
magname2$ = UCASE$(magname2$)
IF magname2$ <> "" THEN magname2P$ = magname2$

'Get the operator's name(s)
PRINT "Enter the operator(s) name(s): ["; operatorP$; "]";
LINE INPUT operator$
IF operator$ <> "" THEN operatorP$ = operator$

'Get the run number
PRINT "What is the run number (1, 2, 3, ...): ["; runP$; "]";
INPUT run$
IF run$ <> "" THEN runP$ = run$

'Get a comment
PRINT "Enter any comment about the run: ["; commentP$; "]";
LINE INPUT comment$
IF comment$ <> "" THEN commentP$ = comment$

'See if everything was entered correctly
PRINT
INPUT "Do you wish to make any changes to the values entered (Y or N): ", yn$
IF yn$ = "Y" OR yn$ = "y" THEN GOTO begin

END SUB

SUB measure

'****************************************************************************
'This subroutine controls the resistance and temperature measurements.
'
'Zachary Wolf
'7/8/94
'****************************************************************************

'Get the desired current
getinom:
PRINT
INPUT "What current do you wish to ramp to? (0<I<1000 A) ", inom!
IF inom! < 0 OR inom! > 1000 THEN
 PRINT : PRINT "The current must be between 0<I<1000 A."
 GOTO getinom:
END IF

'Get the measurement time
gettime:
INPUT "How long do you wish to remain at the desired current? (min) ", tmin!
tsec! = tmin! * 60

'Ramp the magnet
PRINT "Ramping to "; inom!; " Amps..."
CALL imagramp(imagramprateP!, inom!)

'Calculate the number of measurements which will be made
nrt% = tsec! / tbtwnmeassecP%

'Initialize the data arrays
DIM tim$(1 TO nrt%)
DIM imag!(0 TO 2, 1 TO nrt%)
DIM vmag!(0 TO 2, 1 TO nrt%)
DIM rmag!(0 TO 2, 1 TO nrt%)
DIM twin!(0 TO 2, 1 TO nrt%)
DIM twout!(0 TO 2, 1 TO nrt%)
DIM tiron!(0 TO 2, 1 TO nrt%)
DIM tcoil!(0 TO 2, 1 TO nrt%)
DIM tamb!(0 TO 2, 1 TO nrt%)

'Record the temperatures and resistance at regular intervals up to tsec
FOR i% = 1 TO nrt%

'Message
PRINT
PRINT "Beginning a measurement cycle..."
PRINT "Time: "; TIME$

'Record the time of the measurement
tim$(i%) = TIME$
tm! = TIMER

'TEMPERATURE MEASUREMENTS

'Set up the HP3457 to read the temperatures
CALL hp3457setuptc(mxhpchanP%)

'MAGNET 0
'Measure the water in temperature
CALL k7011closecc(mxcardP%, twin0mxchanP%)    'close the multiplexer channel
CALL hp3457readtc(twin!(0, i%))               'measure the temperature
CALL k7011openall                             'open all multiplexer channels

'Measure the water out temperature
CALL k7011closecc(mxcardP%, twout0mxchanP%)
CALL hp3457readtc(twout!(0, i%))
CALL k7011openall

'Measure the temperature of the magnet iron
CALL k7011closecc(mxcardP%, tiron0mxchanP%)
CALL hp3457readtc(tiron!(0, i%))
CALL k7011openall

'Measure the temperature of the measurement coil
CALL k7011closecc(mxcardP%, tcoil0mxchanP%)
CALL hp3457readtc(tcoil!(0, i%))
CALL k7011openall

'Measure the ambient temperature
CALL k7011closecc(mxcardP%, tambmxchanP%)
CALL hp3457readtc(tamb!(0, i%))
CALL k7011openall

'MAGNET 1
'Measure the water in temperature
CALL k7011closecc(mxcardP%, twin1mxchanP%)    'close the multiplexer channel
CALL hp3457readtc(twin!(1, i%))               'measure the temperature
CALL k7011openall                             'open all multiplexer channels

'Measure the water out temperature
CALL k7011closecc(mxcardP%, twout1mxchanP%)
CALL hp3457readtc(twout!(1, i%))
CALL k7011openall

'Measure the temperature of the magnet iron
CALL k7011closecc(mxcardP%, tiron1mxchanP%)
CALL hp3457readtc(tiron!(1, i%))
CALL k7011openall

'Measure the temperature of the measurement coil
CALL k7011closecc(mxcardP%, tcoil1mxchanP%)
CALL hp3457readtc(tcoil!(1, i%))
CALL k7011openall

'Measure the ambient temperature
CALL k7011closecc(mxcardP%, tambmxchanP%)
CALL hp3457readtc(tamb!(1, i%))
CALL k7011openall

'MAGNET 2
'Measure the water in temperature
CALL k7011closecc(mxcardP%, twin2mxchanP%)    'close the multiplexer channel
CALL hp3457readtc(twin!(2, i%))               'measure the temperature
CALL k7011openall                             'open all multiplexer channels

'Measure the water out temperature
CALL k7011closecc(mxcardP%, twout2mxchanP%)
CALL hp3457readtc(twout!(2, i%))
CALL k7011openall

'Measure the temperature of the magnet iron
CALL k7011closecc(mxcardP%, tiron2mxchanP%)
CALL hp3457readtc(tiron!(2, i%))
CALL k7011openall

'Measure the temperature of the measurement coil
CALL k7011closecc(mxcardP%, tcoil2mxchanP%)
CALL hp3457readtc(tcoil!(2, i%))
CALL k7011openall

'Measure the ambient temperature
CALL k7011closecc(mxcardP%, tambmxchanP%)
CALL hp3457readtc(tamb!(2, i%))
CALL k7011openall

'Put the DVM back in a high impedance state
CALL hp3457preset

'MAGNET RESISTANCE MEASUREMENTS

'Measure and store the magnet current
CALL imagmeas(imag1!)
FOR j% = 0 TO 2
 imag!(j%, i%) = imag1!
NEXT j%

'Set up the DVM to measure the magnet voltages
CALL hp3457setupv(mxhpchanP%)

'MAGNET 0
CALL k7011closecc(mxcardP%, vmag0mxchanP%)  'close the multiplexer channel
CALL hp3457readv(vmag!(0, i%))              'measure the magnet voltage
CALL k7011openall                           'open all multiplexer channels
rmag!(0, i%) = vmag!(0, i%) / imag1!     'compute the magnet resistance

'MAGNET 1
CALL k7011closecc(mxcardP%, vmag1mxchanP%)
CALL hp3457readv(vmag!(1, i%))
CALL k7011openall
rmag!(1, i%) = vmag!(1, i%) / imag1!

'MAGNET 2
CALL k7011closecc(mxcardP%, vmag2mxchanP%)
CALL hp3457readv(vmag!(2, i%))
CALL k7011openall
rmag!(2, i%) = vmag!(2, i%) / imag1!

'Write the results to the screen
PRINT
PRINT "Resistance and Temperature (deg C) Measurements"
PRINT "Mag  Imag    Vmag    Rmag    Water   Water  Magnet   Meas          "
PRINT " #    (A)     (V)   (mohm)    In      Out    Iron    Coil   Ambient"
PRINT "--- ------- ------- ------- ------- ------- ------- ------- -------"
FOR m% = 0 TO 2
 PRINT USING " # "; m%;
 PRINT USING " ####.##"; imag!(m%, i%);
 PRINT USING " ##.####"; vmag!(m%, i%);
 PRINT USING " ##.####"; rmag!(m%, i%) * 1000!;
 PRINT USING " ####.##"; twin!(m%, i%);
 PRINT USING " ####.##"; twout!(m%, i%);
 PRINT USING " ####.##"; tiron!(m%, i%);
 PRINT USING " ####.##"; tcoil!(m%, i%);
 PRINT USING " ####.##"; tamb!(m%, i%)
NEXT m%

'Wait between measurements
WHILE TIMER - tm! < tbtwnmeassecP%
WEND

'End of measurement loop
NEXT i%

'Write the results to the log file
CALL logmrt(logfile1P$, 1, nrt%, tim$(), imag!(), vmag!(), rmag!(), twin!(), twout!(), tiron!(), tcoil!(), tamb!())
CALL logmrt(logfile1P$, 0, nrt%, tim$(), imag!(), vmag!(), rmag!(), twin!(), twout!(), tiron!(), tcoil!(), tamb!())
CALL logmrt(logfile2P$, 2, nrt%, tim$(), imag!(), vmag!(), rmag!(), twin!(), twout!(), tiron!(), tcoil!(), tamb!())
CALL logmrt(logfile2P$, 0, nrt%, tim$(), imag!(), vmag!(), rmag!(), twin!(), twout!(), tiron!(), tcoil!(), tamb!())

END SUB