DECLARE SUB rtmeas (tm!)
DECLARE SUB rtdat (logfile$, tim$, imag!, vmag!, rmag!, t1!, t2!, t3!, t4!, t5!)
DECLARE SUB rtlog (logfile$, tim$, imag!, vmag!, rmag!, t1!, t2!, t3!, t4!, t5!)
DECLARE SUB imaggeti (imag!)
DECLARE SUB imagramp (inom!)
DECLARE SUB vmaggetv (vmag!)
DECLARE SUB tmaggettn (n%, tn!)

'****************************************************************************
'Module RT.BAS
'This module performs the resistance and temperature measurements.
'****************************************************************************

'Open the parameter file
REM $INCLUDE: 'param.inc'

'The required parameters are
'tmagt1nameP$
'tmagt2nameP$
'tmagt3nameP$
'tmagt4nameP$
'tmagt5nameP$
'rtdatP$
'rttbtwnmeassecP%
'
'The required parameters are in
'TMAG
'FILE
'RT
'
'Sample RT parameters
'RT
'CONST rttbtwnmeassecP% = 60       '# seconds between RT measurements

SUB rtdat (logfile$, tim$, imag!, vmag!, rmag!, t1!, t2!, t3!, t4!, t5!)

'****************************************************************************
'This subroutine writes the resistance and temperature measurements
'to the log file.
'
'Inputs:
' logfile$, the name of the log file
' tim$, the time the measurement was taken
' imag!, the magnet current
' vmag!, the magnet voltage
' rmag!, the magnet resistance
' t1!, temperature T1 in deg C
' t2!, temperature T2 in deg C
' t3!, temperature T3 in deg C
' t4!, temperature T4 in deg C
' t5!, temperature T5 in deg C
'
'Zachary Wolf
'9/6/94, 12/2/94, 5/8/95
'****************************************************************************

'Keep track of Ncall for header
STATIC ncall%
ncall% = ncall% + 1

'Open the log file
filenum% = FREEFILE
OPEN logfile$ FOR APPEND AS filenum%

'On the first call, write the header
IF ncall% = 1 THEN
 PRINT #filenum%,
 PRINT #filenum%, "                Resistance and Temperature Measurements         "
 PRINT #filenum%,
 PRINT #filenum%, "T1 = "; tmagt1nameP$
 PRINT #filenum%, "T2 = "; tmagt2nameP$
 PRINT #filenum%, "T3 = "; tmagt3nameP$
 PRINT #filenum%, "T4 = "; tmagt4nameP$
 PRINT #filenum%, "T5 = "; tmagt5nameP$
 PRINT #filenum%,
 PRINT #filenum%, "  Time    Imag    Vmag    Rmag     T1      T2      T3      T4      T5   "
 PRINT #filenum%, "           (A)     (V)   (mohm)  (deg C) (deg C) (deg C) (deg C) (deg C)"
 PRINT #filenum%, "-------- ------- ------- ------- ------- ------- ------- ------- -------"
END IF

'Write the values
PRINT #filenum%, USING "&"; tim$;
PRINT #filenum%, USING " ####.##"; imag!;
PRINT #filenum%, USING " ###.###"; vmag!;
PRINT #filenum%, USING " ###.###"; rmag! * 1000!;
PRINT #filenum%, USING " ####.##"; t1!;
PRINT #filenum%, USING " ####.##"; t2!;
PRINT #filenum%, USING " ####.##"; t3!;
PRINT #filenum%, USING " ####.##"; t4!;
PRINT #filenum%, USING " ####.##"; t5!

'Close the log file
CLOSE filenum%

END SUB

SUB rtmain

'****************************************************************************
'This subroutine controls the resistance and temperature measurements.
'
'Zachary Wolf
'9/6/94, 12/2/94, 1/5/95
'****************************************************************************

'Message
PRINT
PRINT "Beginning the magnet resistance and temperature measurement cycle..."

'Get the desired current
getinom:
PRINT
INPUT "What current do you wish to ramp to? (0<I<400 A) ", inom!
IF inom! < 0 OR inom! > 400 THEN
 PRINT : PRINT "The current must be between 0<I<400 A."
 GOTO getinom:
END IF

'Get the measurement time
gettime:
INPUT "How long do you wish to remain at the desired current? (min) ", tmin!
tsec! = tmin! * 60

'Print a header to the screen...
CLS
PRINT
PRINT "Resistance and Temperature Measurements"
PRINT
PRINT "T1 = "; tmagt1nameP$; "     T2 = "; tmagt2nameP$
PRINT "T3 = "; tmagt3nameP$; "     T4 = "; tmagt4nameP$
PRINT "T5 = "; tmagt5nameP$
PRINT
PRINT " Measure  Imag    Vmag    Rmag     T1      T2      T3      T4      T5   "
PRINT "  Time     (A)     (V)   (mohm)  (deg C) (deg C) (deg C) (deg C) (deg C)"
PRINT "-------- ------- ------- ------- ------- ------- ------- ------- -------"

'Record the temperature before the ramp.
PRINT "Measuring the resistance and temperature before ramping..."
CALL rtmeas(tm!)

'Ramp the magnet
CALL imagramp(inom!)

'Calculate the number of measurements which will be made
nrt% = 1 + tsec! / rttbtwnmeassecP%

'Record the temperatures and resistance at regular intervals up to tsec
FOR i% = 1 TO nrt%

'Make a resistance and temperature measurement.
CALL rtmeas(tm!)

'Wait between measurements
WHILE TIMER - tm! < rttbtwnmeassecP%
WEND

'End of measurement loop
NEXT i%

'Ramp to 0 amps
CALL imagramp(0!)

END SUB

SUB rtmeas (tm!)

'Message
'PRINT : PRINT
'PRINT "Time: "; TIME$; "   Beginning a R&T measurement cycle..."

'Record the time of the measurement
tim$ = TIME$
tm! = TIMER

'TEMPERATURE MEASUREMENTS

'Measure T1
CALL tmaggettn(1, t1!)

'Measure T2
CALL tmaggettn(2, t2!)

'Measure T3
CALL tmaggettn(3, t3!)

'Measure T4
CALL tmaggettn(4, t4!)

'Measure T5
CALL tmaggettn(5, t5!)

'MAGNET RESISTANCE MEASUREMENTS

'Measure and store the magnet current
CALL imaggeti(imag!)

'Measure the magnet voltage
CALL vmaggetv(vmag!)

'Compute the magnet resistance
rmag! = vmag! / imag!

'Write the results to the screen
'PRINT
'PRINT "Resistance and Temperature Measurements"
'PRINT
'PRINT " Measure  Imag    Vmag    Rmag     T1      T2      T3      T4      T5   "
'PRINT "  Time     (A)     (V)   (mohm)  (deg C) (deg C) (deg C) (deg C) (deg C)"
'PRINT "-------- ------- ------- ------- ------- ------- ------- ------- -------"
PRINT tim$;
PRINT USING " ####.##"; imag!;
PRINT USING " ###.###"; vmag!;
PRINT USING " ###.###"; rmag! * 1000!;
PRINT USING " ####.##"; t1!;
PRINT USING " ####.##"; t2!;
PRINT USING " ####.##"; t3!;
PRINT USING " ####.##"; t4!;
PRINT USING " ####.##"; t5!
'PRINT
'PRINT "T1 = "; tmagt1nameP$; "     T2 = "; tmagt2nameP$
'PRINT "T3 = "; tmagt3nameP$; "     T4 = "; tmagt4nameP$
'PRINT "T5 = "; tmagt5nameP$

'Write the results to the data file
CALL rtdat(rtdatP$, tim$, imag!, vmag!, rmag!, t1!, t2!, t3!, t4!, t5!)

END SUB