DECLARE SUB rtlog (logfile$, nrt%, tim$(), imag!(), vmag!(), rmag!(), t1!(), t1name$, t2!(), t2name$, t3!(), t3name$, t4!(), t4name$, t5!(), t5name$)
DECLARE SUB imaggeti (imag!)
DECLARE SUB imagramp (inom!)
DECLARE SUB vmaggetv (vmag!)
DECLARE SUB tmaggettn (n%, tn!)

'****************************************************************************
'Module RT.BAS
'This module performs the resistance and temperature measurements.
'****************************************************************************

'Open the parameter file
REM $INCLUDE: 'param.inc'

SUB rt

'****************************************************************************
'This subroutine controls the resistance and temperature measurements.
'
'Zachary Wolf
'9/6/94, 12/2/94, 1/5/95
'****************************************************************************

'Message
PRINT
PRINT "Beginning the magnet resistance and temperature measurement cycle..."

'Get the desired current
getinom:
PRINT
INPUT "What current do you wish to ramp to? (0<I<500 A) ", inom!
IF inom! < 0 OR inom! > 500 THEN
 PRINT : PRINT "The current must be between 0<I<500 A."
 GOTO getinom:
END IF

'Get the measurement time
gettime:
INPUT "How long do you wish to remain at the desired current? (min) ", tmin!
tsec! = tmin! * 60

'Ramp the magnet
PRINT "Ramping to "; inom!; " Amps..."
CALL imagramp(inom!)

'Calculate the number of measurements which will be made
nrt% = 1 + tsec! / tbtwnmeassecP%

'Initialize the data arrays
DIM tim$(1 TO nrt%)
DIM imag!(1 TO nrt%)
DIM vmag!(1 TO nrt%)
DIM rmag!(1 TO nrt%)
DIM t1!(1 TO nrt%)
DIM t2!(1 TO nrt%)
DIM t3!(1 TO nrt%)
DIM t4!(1 TO nrt%)
DIM t5!(1 TO nrt%)

'Record the temperatures and resistance at regular intervals up to tsec
FOR i% = 1 TO nrt%

'Message
PRINT
PRINT "Beginning a measurement cycle..."
PRINT "Time: "; TIME$

'Record the time of the measurement
tim$(i%) = TIME$
tm! = TIMER

'TEMPERATURE MEASUREMENTS

'Measure T1
CALL tmaggettn(1, t1!(i%))

'Measure T2
CALL tmaggettn(2, t2!(i%))

'Measure T3
CALL tmaggettn(3, t3!(i%))

'Measure T4
CALL tmaggettn(4, t4!(i%))

'Measure T5
CALL tmaggettn(5, t5!(i%))

'MAGNET RESISTANCE MEASUREMENTS

'Measure and store the magnet current
CALL imaggeti(imag!(i%))

'Measure the magnet voltage
CALL vmaggetv(vmag!(i%))

'Compute the magnet resistance
rmag!(i%) = vmag!(i%) / imag!(i%)

'Write the results to the screen
PRINT
PRINT "Resistance and Temperature Measurements"
PRINT "T1 = "; t1P$
PRINT "T2 = "; t2P$
PRINT "T3 = "; t3P$
PRINT "T4 = "; t4P$
PRINT "T5 = "; t5P$
PRINT
PRINT " Imag    Vmag    Rmag     T1      T2      T3      T4      T5   "
PRINT "  (A)     (V)   (mohm)  (deg C) (deg C) (deg C) (deg C) (deg C)"
PRINT "------- ------- ------- ------- ------- ------- ------- -------"
PRINT USING "####.##"; imag!(i%);
PRINT USING " ###.###"; vmag!(i%);
PRINT USING " ###.###"; rmag!(i%) * 1000!;
PRINT USING " ####.##"; t1!(i%);
PRINT USING " ####.##"; t2!(i%);
PRINT USING " ####.##"; t3!(i%);
PRINT USING " ####.##"; t4!(i%);
PRINT USING " ####.##"; t5!(i%)

'Wait between measurements
WHILE TIMER - tm! < tbtwnmeassecP%
WEND

'End of measurement loop
NEXT i%

'Write the results to the dat file
CALL rtlog(rtdatP$, nrt%, tim$(), imag!(), vmag!(), rmag!(), t1!(), t1P$, t2!(), t2P$, t3!(), t3P$, t4!(), t4P$, t5!(), t5P$)

'Write the results to the log file
CALL rtlog(logfileP$, nrt%, tim$(), imag!(), vmag!(), rmag!(), t1!(), t1P$, t2!(), t2P$, t3!(), t3P$, t4!(), t4P$, t5!(), t5P$)

'Ramp to 0 amps
CALL imagramp(0!)

END SUB

SUB rtlog (logfile$, nrt%, tim$(), imag!(), vmag!(), rmag!(), t1!(), t1name$, t2!(), t2name$, t3!(), t3name$, t4!(), t4name$, t5!(), t5name$)

'****************************************************************************
'This subroutine writes the resistance and temperature measurements
'to the log file.
'
'Inputs:
' logfile$, the name of the log file
' nrt%, the number of resistance and temperature measurements
' tim$(1 to nrt%), the times the measurements were taken
' imag!(1 to nrt%), the magnet current
' vmag!(1 to nrt%), the magnet voltage
' rmag!(1 to nrt%), the magnet resistance
' t1!(1 to nrt%), temperature T1 in deg C
' t1name$, name of object whose temperature is T1
' t2!(1 to nrt%), temperature T2 in deg C
' t2name$, name of object whose temperature is T2
' t3!(1 to nrt%), temperature T3 in deg C
' t3name$, name of object whose temperature is T3
' t4!(1 to nrt%), temperature T4 in deg C
' t4name$, name of object whose temperature is T4
' t5!(1 to nrt%), temperature T5 in deg C
' t5name$, name of object whose temperature is T5
'
'Zachary Wolf
'9/6/94, 12/2/94
'****************************************************************************

'Open the log file
filenum% = FREEFILE
OPEN logfile$ FOR APPEND AS filenum%

'Write the header
PRINT #filenum%,
PRINT #filenum%, "        Resistance and Temperature Measurements         "
PRINT #filenum%,
PRINT #filenum%, "T1 = "; t1name$
PRINT #filenum%, "T2 = "; t2name$
PRINT #filenum%, "T3 = "; t3name$
PRINT #filenum%, "T4 = "; t4name$
PRINT #filenum%, "T5 = "; t5name$
PRINT #filenum%,
PRINT #filenum%, "  Time    Imag    Vmag    Rmag     T1      T2      T3      T4      T5   "
PRINT #filenum%, "           (A)     (V)   (mohm)  (deg C) (deg C) (deg C) (deg C) (deg C)"
PRINT #filenum%, "-------- ------- ------- ------- ------- ------- ------- ------- -------"
FOR i% = 1 TO nrt%
 PRINT #filenum%, USING "&"; tim$(i%);
 PRINT #filenum%, USING " ####.##"; imag!(i%);
 PRINT #filenum%, USING " ###.###"; vmag!(i%);
 PRINT #filenum%, USING " ###.###"; rmag!(i%) * 1000!;
 PRINT #filenum%, USING " ####.##"; t1!(i%);
 PRINT #filenum%, USING " ####.##"; t2!(i%);
 PRINT #filenum%, USING " ####.##"; t3!(i%);
 PRINT #filenum%, USING " ####.##"; t4!(i%);
 PRINT #filenum%, USING " ####.##"; t5!(i%)
NEXT i%

'Close the log file
CLOSE filenum%

END SUB