SUB logbl (logfile$, imagave!, bl!)

'****************************************************************************
'This subroutine writes a summary to the log file.
'
'Inputs:
' logfile$, the name of the log file
' imagave!, the average magnet current during the run
' bl!, the measured integrated field strength
'
'Zachary Wolf
'6/22/94
'****************************************************************************

'Open the log file
filenum% = FREEFILE
OPEN logfile$ FOR APPEND AS filenum%

'Write a header
PRINT #filenum%,
PRINT #filenum%, "Integrated Field Strength:"

'Write the values
PRINT #filenum%, "The average magnet current during the run, Imagave = "; imagave!; " A"
PRINT #filenum%, "The integrated field strength BL = "; bl!; " Tm"

'Close the log file
CLOSE filenum%

END SUB

SUB logbnmrh (logfile$, ns%, z!(), imag!(), bhall!(), bnmr!(), bcorr!())

'****************************************************************************
'This subroutine writes a summary to the log file.
'
'Inputs:
' logfile$, the name of the log file
' ns%, the number of z steps
' z!(0 to ns%), the z positions
' imag!(0 to ns%), the measured magnet currents
' bhall!(0 to ns%), the measured magnetic field strengths from the Hall probe
' bnmr!(0 to ns%), the measured magnetic field strengths from the NMR probe
' bcorr!(0 to ns%), the corrected magnetic field at each point
'
'Zachary Wolf
'6/22/94
'****************************************************************************

'Open the log file
filenum% = FREEFILE
OPEN logfile$ FOR APPEND AS filenum%

'Write a header
PRINT #filenum%,
PRINT #filenum%, "NMR and Hall Probe Measurements:"

'Write the header
PRINT #filenum%, "   Z      Zpos         I        Bhall      Bnmr       Bcorr  "
PRINT #filenum%, "  num      (m)        (A)        (T)        (T)        (T)   "
PRINT #filenum%, " -----  ---------  ---------  ---------  ---------  ---------"

'Write the values
FOR i% = 0 TO ns%
 PRINT #filenum%, USING " #####"; i%;
 PRINT #filenum%, USING "  ##.######"; z!(i%);
 PRINT #filenum%, USING "  ####.####"; imag!(i%);
 PRINT #filenum%, USING "  ##.######"; bhall!(i%);
 PRINT #filenum%, USING "  ##.######"; bnmr!(i%);
 PRINT #filenum%, USING "  ##.######"; bcorr!(i%)
NEXT i%

'Close the log file
CLOSE filenum%

END SUB

SUB logplot (logfile$, magname$, run$, ns%, z!(), imag!(), bhall!(), bnmr!(), bcorr!())

'****************************************************************************
'This subroutine writes a summary to the plot file.
'
'Inputs:
' logfile$, the name of the log file
' magname$, magnet name
' run$, run number
' ns%, the number of z steps
' z!(0 to ns%), the z positions
' imag!(0 to ns%), the measured magnet currents
' bhall!(0 to ns%), the measured magnetic field strengths from the Hall probe
' bnmr!(0 to ns%), the measured magnetic field strengths from the NMR probe
' bcorr!(0 to ns%), the corrected magnetic field strengths
'
'Zachary Wolf
'6/23/94
'****************************************************************************

'Open the log file
filenum% = FREEFILE
OPEN logfile$ FOR APPEND AS filenum%

'Plot title
PRINT #filenum%, "/et g '" + magname$ + ", Run " + run$ + "'"

'Write the values
FOR i% = 0 TO ns%
 PRINT #filenum%, USING " #####"; i%;
 PRINT #filenum%, USING "    ####.####"; z!(i%);
 PRINT #filenum%, USING "    ####.####"; imag!(i%);
 PRINT #filenum%, USING "    ##.######"; bhall!(i%);
 PRINT #filenum%, USING "    ##.######"; bnmr!(i%);
 PRINT #filenum%, USING "    ##.######"; bcorr!(i%)
NEXT i%

'Close the log file
CLOSE filenum%

END SUB